Problem solve Get help with specific problems with your technologies, process and projects.

Put dynamic text on your iSeries sign-on screen

This sign-on screen layout will help you to inform your users about system downtime or any other important information.

To be able to inform your users about system downtime or any other important information, the following sign-on screen layout has been developed.

Let me explain to you how this works:

The five output fields in line 6,7,8,9 and 10 have a length of 55 characters and will be used to display your message.

The output field at line 18 with length 40 is used to display the OS/400 installed version. The output fields at line 19 with length 40 is used to display the actual CUMPTF. (Of course these two fields can be used for displaying any other information.)

The content of these 7 fields is stored in *MSGF *LIBL/SIGNONMSG.

Within this *MSGF MSGID 0001 is used for the first 55 character field Within this *MSGF MSGID 0002 is used for the second 55 character field .....

The MSGID SHT0001 is used to store the 40 character output field at line 18. The MSGID SHT0002 is used to store the 40-character output field at line 19.

Using command WRKMSGF SIGNONMSG allows you to change the content displayed on the sign-on screen dynamically.

To install the new sign-on screen screen:

1. Create *MSFG SIGNONMSG in *LIBL.
2. Add message descriptions SND0001-SND0005, SHT0001 and SHT0002.
3. Design your own sign-on screen based on the following DDS-Source.
4. Compile the new DDS-source (be aware to give a new name, I would suggest you to rename it to your own system name). Don't forget to specify MAXDEV(256) on command CRTDSPF.
5. Change your SBSD QINTER (using command CHGSBSD SBSD(QINTER) SGNDSPF(*LIBL/SIGNON_DYN) to specify the new sign-on display file (new screen will become active the next time you stop-start SBS QINTER.)

Remarks:

* To end and restart your QINTER SBS you have whether to go to the system console or to enter TFRJOB JOBQ(QCTL) on your PC session.
* By ending SBS QINTER all users logged on will be disconnected.
* Do not overwrite the IBM original QDSIGNON display file.

This change will also remove the "sign-on screen" input fields:

* Program/procedure
* Menu
* Current library
* As suggested in our company security guidelines and even in IBM's book "Tips and tools for securing your iSeries."


 
  
  
     A                                      DSPSIZ(24 80 *DS3)
     A                                      CHGINPDFT
     A          R SIGNON
     A                                      CLEAR
     A                                      BLINK
     A                                  1 23'             Sign On             '
     A                                      DSPATR(HI)
     A                                  2 48'System  . . . . . :'
     A                                      COLOR(WHT)
     A            SYSNAME        8A  O  2 70COLOR(WHT)
     A                                  3 48'Subsystem . . . . :'
     A                                      COLOR(WHT)
     A            SBSNAME       10A  O  3 70COLOR(WHT)
     A                                  4 48'Display . . . . . :'
     A                                      COLOR(WHT)
     A            DEVNAME       10A  O  4 70COLOR(WHT)
     A                                  2  4'User  . . . . . . .'
     A                                      COLOR(WHT)
     A            USERID        10A  B  2 24COLOR(WHT)
     A  01                              3  4'Password  . . . . .'
     A                                      COLOR(WHT)
     A  01        PASSWRD       10A  I  3 24DSPATR(ND)
     A            PROGRAM       10A  B  2 36CHECK(LC)
     A                                      DSPATR(PR)
     A                                      DSPATR(ND)
     A            MENU          10A  B  3 36CHECK(LC)
     A                                      DSPATR(PR)
     A                                      DSPATR(ND)
     A            CURLIB        10A  B  5 70CHECK(LC)
     A                                      DSPATR(PR)
     A                                      DSPATR(ND)
     A  02        QSNERROR      80A  O 24  1DSPATR(HI)
     A            COPYRIGHT     40A  O 24 40DSPATR(HI)
     A            UBUFFER      128A  H
     A                                  9 61'                 '
     A                                      DSPATR(HI)
     A                                 10 61'              '
     A                                      DSPATR(HI)
     A                                 14 61'                    '
     A                                      DSPATR(HI)
     A            SNDMSG1       55A  O  6  4MSGID(SND 0001 SIGNONMSG)
     A                                      DSPATR(HI)
     A                                      COLOR(RED)
     A            SNDMSG2       55A  O  7  4MSGID(SND 0002 SIGNONMSG)
     A                                      DSPATR(HI)
     A                                      COLOR(RED)
     A            SNDMSG3       55A  O  8  4MSGID(SND 0003 SIGNONMSG)
     A                                      DSPATR(HI)
     A                                      COLOR(RED)
     A            SNDMSG4       55A  O  9  4MSGID(SND 0004 SIGNONMSG)
     A                                      DSPATR(HI)
     A                                      COLOR(RED)
     A            SNDMSG5       55A  O 10  4MSGID(SND 0005 SIGNONMSG)
     A                                      DSPATR(HI)
     A                                      COLOR(RED)
     A            SHT0001       40A  O 18 40MSGID(SHT 0001 SIGNONMSG)
     A            SHT0002       40A  O 19 40MSGID(SHT 0002 SIGNONMSG)

  
  

==================================
MORE INFORMATION ON THIS TOPIC
==================================

The Best Web Links: Tips, tutorials and more.

Ask your systems management questions--or help out your peers by answering them--in our live discussion forums.

Read this Search400.com Featured Topic: Managing your iSeries.

Dig Deeper on Performance

Start the conversation

Send me notifications when other members comment.

Please create a username to comment.

-ADS BY GOOGLE

SearchDataCenter

Close